IRCRehberi.Net- Türkiyenin En iyi IRC ve Genel Forum Sitesi  
 sohbet
derya sohbet


mIRC Scripting Sorunları - Yardım mIRC Scripting ile ilgili sorunlariniza ait güncel yanıtlara bu başlık altından ulaşabilirsiniz.

11Beğeni(ler)


 
 
Seçenekler Stil
Alt 12 Mart 2021, 20:49   #1
NCL
Mahrez - ait Kullanıcı Resmi (Avatar)

Standart Winamp eklentisi hakkında.

Merhabalar , bir kaç gün önce şöyle bir soru gelmişti.
Scriptte dinlediğim müzik statuste ve istediğim kanallara yansısin.

Kod

menu menubar,channel,status {
TMS Mp3 Player:taitmsmp3
-
}
alias taitmsmp3 {
if ($dialog(taitmsmp3) == $null) { noop $dialog(taitmsmp3,taitmsmp3,-2) }
else { .echo -at - Mp3 ON! }
}
alias -l mp3.title.role {
if ($dialog(taitmsmp3)) {
if ($insong) {
var %b = $insong.fname,%c = $sound(%b).artist,%d = $sound(%b).title
if (%c) && (%d) { var %a = %c - %d }
else { var %a = $nopath(%b) }
if (!%mp3.x) { %mp3.x = $calc($len(%a)) }
if ($dialog(taitmsmp3)) did -ra taitmsmp3 101 $replace($wrap($right($str($chr(160),60) $+ %a,%mp3.x),tahoma,1,1000,0,1),$chr(32),$chr(160))
}
dec %mp3.x
}
}
alias mp3.spam {
if ($server == $null) { echo -st $replace(%mp3.spam.st,[b],,[u],,[k],,[song],%playingnow,[size],%mp3.size,[length],%mp3.time) 14[(4TMS 12MP3 Player14)] | echo -s - }
if ($active != $chan) { echo -st $replace(%mp3.spam.st,[b],,[u],,[k],,[song],%playingnow,[size],%mp3.size,[length],%mp3.time) 14[(4TMS 12MP3 Player14)] | echo -s - }
else {
if (%mp3.msg == amsg) { amsg $replace(%mp3.spam.st,[b],,[u],,[k],,[song],%playingnow,[size],%mp3.size,[length],%mp3.time) 14[(4TMS 12MP3 Player14)] }
if (%mp3.msg == ame) { ame $replace(%mp3.spam.st,[b],,[u],,[k],,[song],%playingnow,[size],%mp3.size,[length],%mp3.time) 14[(4TMS 12MP3 Player14)] }
if (%mp3.msg == none) { echo -at $replace(%mp3.spam.st,[b],,[u],,[k],,[song],%playingnow,[size],%mp3.size,[length],%mp3.time) 14[(4TMS 12MP3 Player14)] }
}
}
alias mp3.info.song {
set %mp3.size $round($calc($file($read(playlist.txt,%songnum)).size / 1048576),2) MB
set %mp3.time $right($duration($calc($sound($read(playlist.txt,%songnum)).length / 1000),3),-3) Sn.
if ($dialog(taitmsmp3)) {
did -ra taitmsmp3 804 $round($calc($file($read(playlist.txt,%songnum)).size / 1048576),2) MB
did -ra taitmsmp3 802 $right($duration($calc($sound($read(playlist.txt,%songnum)).length / 1000),3),-3) Sn.
did -c taitmsmp3 202 $($+(%,songnum),2)
did -s taitmsmp3 202 $($+(%,songnum),2)
}
}
alias -l mp3.back.song {
if (%songnum < $lines(playlist.txt)) {
dec %songnum
splay $read(playlist.txt,%songnum)
set %playingnow $nopath($read(playlist.txt,%songnum))
mp3.info.song
mp3.spam

}
}
alias -l mp3.play {
if ($did($dname,202).seltext == $null) { echo -at Lütfen Listeden Bir Şarkı Seçiniz.. | halt }
set %mp3.music.on 1
set %songnum $did(202).sel
if ($read(playlist.txt,%songnum) == $null) { halt }
else { splay $read(playlist.txt,%songnum) }
.timermp3pos 0 1 mp3.pos $dname 103
.timermp3 0 1 mp3.rem.song
.timermp32 0 1 mp3.count
.timermp3.player -m 0 150 mp3.title.role
set %playingnow $nopath($read(playlist.txt,%songnum))
mp3.info.song
mp3.spam
}
alias -l mp3.check.play {
set %mp3.music.on 1
if (%mp3.con.play) {
if (%songnum < $lines(playlist.txt)) {
inc %songnum
splay $read(playlist.txt,%songnum)
set %playingnow $nopath($read(playlist.txt,%songnum))
mp3.info.song
mp3.spam
}
}
elseif (%mp3.shuffle.play) {
:ransong
var %song = $read(playlist.txt)
if ( $readn == %songnum ) goto ransong
set %songnum $readn
splay %song
set %playingnow $nopath($read(playlist.txt,%songnum))
mp3.info.song
mp3.spam
}
elseif (%mp3.repeat.play) {
splay $read(playlist.txt,%songnum)
set %playingnow $nopath($read(playlist.txt,%songnum))
}
}
alias mp3.pos {
if (($1) && ($2)) {
did -c $1 $2 $calc(($insong.pos / $insong.length) * 100)
}
}
alias mp3.count {
did -ra taitmsmp3 104 $($remove($duration($calc($insong.pos / 1000 ),3),00:0),5)
}
alias -l mp3.rem.song {
did -ra taitmsmp3 102 - $+ $asctime($round($calc(($insong.length - $insong.pos) / 1000),0),n:ss),none)
}
alias -l mp3.pause {
if ($inmp3) {
if (!$inmp3.pause) { splay pause }
else {
splay resume
}
}
}
alias -l mp3.load.init {
if (%mp3.music.on) { .timermp3 0 1 mp3.rem.song | .timermp3pos 0 1 mp3.pos $dname 103 | .timermp3.player -m 0 150 mp3.title.role | .timermp32 0 1 mp3.count }
if (%mp3.msg == ame) { did -c $dname 601 }
if (%mp3.msg == amsg) { did -c $dname 602 }
if (%mp3.msg == none) { did -c $dname 603 }
if (%mp3.con.play) { did -c $dname 502 }
if (%mp3.shuffle.play) { did -c $dname 501 }
if (%mp3.repeat.play) { did -c $dname 503 }
did -ra $dname 300 Ses Seviyesi $chr(40) $+ $int($calc(($vol(master) / 65535) * 100)) $+ % $+ $chr(41)
did -c $dname 301 $vol(master)
if ($vol(master).mute == $true) { did -c $dname 302 | did -b $dname 301 | did -ar $dname 300 Ses (Sessiz) }
var %a = 1, %b = playlist.txt
while ( %a <= $lines(%b) ) {
did -a $dname 202 $left($nopath($read(%b,%a)),-4)
inc %a
}
did -a $dname 806 $did(202).lines
mp3.info.song
}

alias -l mp3.add.dir {
if ($sdir(.,Choose mp3 directory)) {
.remove playlist.txt
did -r $dname 202
write -c playlist.txt
var %x = 1, %d = $v1
while ( $findfile(%d,*.mp3,%x) ) {
write playlist.txt $v1
did -a $dname 202 $left($nopath($v1),-4)
inc %x
}
did -ra $dname 806 $calc(%x -1)
}
}
alias -l mp3.rem.dir {
.remove playlist.txt
splay stop
unset %mp3.x
unset %songnum
unset %playingnow
did -r $dname 101,202,802,804,806
if ($read(playlist.txt,%songnum) == $null) { halt }
}
dialog taitmsmp3 {
title "TMS MP3 PLAYER v0.1"
size -1 -1 260 192
option dbu

menu "Menu", 1
item "KAPAT", 2, 1, cancel

box "Şu Çalan Parça..", 100, 2 2 257 19
text "", 101, 4 10 250 10, read center
edit "", 102, 228 23 31 10, read center
scroll "", 103, 33 24 194 8, range 0 100 horizontal bottom
edit "", 104, 2 23 31 10, read center

box "MP3 Listesi..", 200, 2 35 128 156
list 202, 4 44 122 143, size hsbar vsbar radio

box "Ses", 300, 131 35 127 20
scroll "", 301, 158 44 98 8, horizontal bottom range 0 65535
check "Sessiz", 302, 135 44 25 10

box "Ayarlar", 400, 131 55 127 23
button "Çaldır", 401, 168 62 52 12, flat
button "İptal", 402, 221 62 20 12, flat
button "<<", 403, 133 62 13 12, flat
button ">>", 404, 242 62 13 12, flat
button "Durdur", 405, 147 62 20 12, flat

box "Çalma Türleri", 500, 131 78 127 21
radio "Karıştır", 501, 132 84 31 10, flat group
radio "Normal", 502, 179 84 38 10, flat
radio "Tekrarla", 503, 229 84 28 10, flat

box "Reklam", 600, 131 99 127 24
radio "/AME", 601, 132 108 19 10, group flat left
radio "/AMSG", 602, 165 108 21 10, flat left
radio "Hiçbiri", 603, 195 108 21 10, flat left
button "Reklam At", 604, 219 107 37 12

box "MP3 Dosyası Seç", 700, 131 122 127 24
button "Listeyi Kaydet", 702, 132 130 40 12, flat
button "Kaldır", 703, 216 130 40 12, flat

box "Mp3 Bilgileri", 800, 131 145 61 46
text "Uzunluk", 801, 133 154 25 8, center
edit "", 802, 158 153 32 11, read center
text "Boyut", 803, 133 166 25 8, center
edit "", 804, 158 165 32 11, read center
text "Toplam Mp3", 805, 133 179 25 8, center
edit "", 806, 158 177 32 11, read center

button "KAPAT", 900, 206 160 40 20, flat ok
}
dialog taimp3reklam {
title "MP3 Reklamı At"
size 400 250 220 75
option dbu
box "", 1, 2 2 214 50
text "Reklam:", 2, 4 11 20 8
edit "", 3, 30 9 185 12
text "Çalan: [song] - Uzunluk: [length] - Boyut: [size]", 4, 3 25 120 30
text "Bold: [b] - Renk: [c] - Underline: [u] ", 5, 3 40 110 8
button "Kaydet", 6, 179 60 37 12,ok
}
on *:dialog:taimp3reklam:*:*:{
if ($devent == init) {
did -a $dname 3 %mp3.spam.st
}
if ($devent == sclick) {
if ($did = 6) { set %mp3.spam.st $did($dname,3) }
}
}
on *:dialog:taitmsmp3:*:*:{
if ($devent == init) { mp3.load.init }
if ($devent == sclick) {
if ($did = 302) {
if ($vol(master).mute == $true) { vol -vu2 | did -u $dname 302 | did -e $dname 301 | did -ar $dname 300 Ses $chr(40) $+ $int($calc(($vol(master) / 65535) * 100)) $+ % $+ $chr(41) }
elseif ($vol(master).mute == $false) { vol -vu1 | did -c $dname 302 | did -b $dname 301 | did -ar $dname 300 Ses (Sessiz) }
}
if ($did = 401) { mp3.play }
if ($did = 402) { splay stop | set %mp3.music.on 0 | did -r $dname 101,802,804 | unset %playingnow | unset %mp3.x | unset %songnum }
if ($did = 403) { mp3.back.song | unset %mp3.x }
if ($did = 404) { mp3.check.play | unset %mp3.x }
if ($did = 405) { mp3.pause }
if ($did = 501) { set %mp3.shuffle.play $did($dname,501).state | set %mp3.repeat.play 0 | set %mp3.con.play 0 }
if ($did = 502) { set %mp3.con.play $did($dname,502).state | set %mp3.repeat.play 0 | set %mp3.shuffle.play 0 }
if ($did = 503) { set %mp3.repeat.play $did($dname,503).state | set %mp3.shuffle.play 0 | set %mp3.con.play 0 }
if ($did = 601) { set %mp3.msg ame }
if ($did = 602) { set %mp3.msg amsg }
if ($did = 603) { set %mp3.msg none }
if ($did = 604) { dialog -m taimp3reklam taimp3reklam }
if ($did = 702) { mp3.add.dir | unset %mp3.x }
if ($did = 703) { mp3.rem.dir | unset %mp3.x }
}
if ($devent == dclick) {
if ($did = 202) { mp3.play }
}
if ($devent == scroll) {
if ($did = 103) { .timerposition -p | splay -p seek $int($calc(($did(103).sel / 100) * $insong.length)) | .timerposition -r }
if ($did = 301) { vol -v $did($did).sel | did -ar $dname 300 Ses $chr(40) $+ $int($calc(($vol(master) / 65535) * 100)) $+ % $+ $chr(41) }
}
if ($devent == close) { .timermp3pos off | .timermp3 off | .timermp3.player off | unset %mp3.x | .timermp32 off }
}
on *:MP3END: {
mp3.check.play
mp3.info.song
}
iyi IR ler.
________________

"Fark etmek acıydı ama gerekliydi."

Konu Feragat tarafından (06 Ağustos 2022 Saat 10:55 ) değiştirilmiştir..
 
Alt 12 Mart 2021, 21:05   #2
She
✰ ÖzeL..
She - ait Kullanıcı Resmi (Avatar)

Standart

Emeğinize sağlık paylaşım için teşekkür ederiz @ Kaan- umarım ki buradaki kişilere de faydalı olucaktır.

________________

~ E & B ~
 
Alt 12 Mart 2021, 23:14   #3
~Ölüm Çiçeği~
LaviNia - ait Kullanıcı Resmi (Avatar)

Standart

Emeğinize sağlık

________________

Bazen de yıldızlar bakar.
İnsanlar kayar hayatımızdan..

 
Alt 13 Mart 2021, 12:09   #4
✰ ÖzeL..
oMeN - ait Kullanıcı Resmi (Avatar)

Standart

Emeğine sağlık @[Üye Olmadan Linkleri Göremezsiniz. Üye Olmak için TIKLAYIN...]

________________

Edep; aklın Tercümanıdır. İnsan edebi kadar akıllı, Aklı kadar şerefli, Şerefi kadar Kıymetlidir. Massive..




~ E & B ~
 
Alt 29 Mart 2021, 09:56   #5
Sim
civciv~🐥
Sim - ait Kullanıcı Resmi (Avatar)

Standart

paylasim icin tesekkürler emeginize saglik

________________

Hope. . . ✨
 
Alt 29 Mart 2021, 11:12   #6
Guest
Beatrice - ait Kullanıcı Resmi (Avatar)

Standart

Emeğinize sağlık

 
Alt 29 Mart 2021, 21:20   #7
Lâ Tahzen innALLÂHe Meâna
Furkan - ait Kullanıcı Resmi (Avatar)

Standart

Emeğine sağlık kardeşim paylaşım için teşekkürler.

________________

Düştüğüm her kuyudan mücadele ederek çıkmayı çocukken öğrendim.

"Aslolan hayattır, hayat da BEŞİKTAŞ"

[Üye Olmadan Linkleri Göremezsiniz. Üye Olmak için TIKLAYIN...]
[Üye Olmadan Linkleri Göremezsiniz. Üye Olmak için TIKLAYIN...]
 
Alt 29 Mart 2021, 23:12   #8
Cumhuriyet Kadını
Reyhan - ait Kullanıcı Resmi (Avatar)

Standart

Emeğine sağlık @[Üye Olmadan Linkleri Göremezsiniz. Üye Olmak için TIKLAYIN...]

________________

ellerinde bir güldüm ,
soldum .
 
Alt 04 Nisan 2021, 02:38   #9
Mutena
Ruyanur - ait Kullanıcı Resmi (Avatar)

Standart

Emeğinize sağlık.

________________

"hakikâte giden yolda, meşakkatsiz bir varış yoktur."




 
Alt 05 Nisan 2021, 20:42   #10
YGT
YGT - ait Kullanıcı Resmi (Avatar)

Standart

emeğine sağlık reis

 


Konuyu Toplam 1 Üye okuyor. (0 Kayıtlı üye ve 1 Misafir)
 
Seçenekler
Stil

Yetkileriniz
Konu Acma Yetkiniz Yok
Cevap Yazma Yetkiniz Yok
Eklenti Yükleme Yetkiniz Yok
Mesajınızı Değiştirme Yetkiniz Yok

BB code is Açık
Smileler Açık
[IMG] Kodları Açık
HTML-Kodu Kapalı
Trackbacks are Kapalı
Pingbacks are Kapalı
Refbacks are Kapalı





Tüm Zamanlar GMT +3 Olarak Ayarlanmış. Şuanki Zaman: 18:27.