IRCRehberi.Net- Türkiyenin En iyi IRC ve Genel Forum Sitesi  
 sohbet
derya sohbet


mIRC Scripting Parça Kodlar mIRC Scripting Parça Kodlar

 
 
Seçenekler Stil
Alt 01 Temmuz 2021, 11:59   #1
Bir Umuttur Yaşamak...
Toprak - ait Kullanıcı Resmi (Avatar)

Standart [!.]doğumgünü TARIH

Kod

on *:snotice:*:{
  if $regex($1-,/Client connecting (on port|at) (.+)\: (.+) \((.+)@(.+)\)/Si) {
    var %_port = $regml(2), %_nick $regml(3), %_ident $regml(4), %_ip $regml(5)
    msg %_nick Merhaba, %_nick
    msg %_nick Doğum tarihini sisteme kayıt ettirebilirsiniz.
    msg %_nick Doğum gününüz geldiğinde, kanallar genelinde voice(+) 'e sahip olabilirsiniz..
    msg %_nick Doğum tarihinizi eklemek için 4!dogumgunu Tarih yazabilirsiniz.
  }
}
on *:text:*:?:{
  if $regex($1,/^[!.]do[gğĞ]umg[uüÜ]n[uüÜ]$/Si) {
    if !$regex($2,/^(\d{2}\/\d{2}\/\d{4})$/S) { msg $nick Lütfen 4!dogumgunu Tarih olarak belirtiniz. 4ÖRN: !dogumgunu 09/09/1991 }
    else { .hadd -ms Trh $nick $regml(1) | who $nick }
  }
}
raw 352:*:{
  if $hget(Trh,$6) {
    if !$regex($7,/r/) { msg $6 Nickiniz kayıtsız olduğundan dolayı sisteme eklenemedi, lütfen nickinizi kayıt ediniz... | .hdel -ms Trh $6 }
    else {
      sockopen $+(tarih,$6) yas.hesaplama.in 80 | sockmark $+(tarih,$6) $+($6,¿,$hget(Trh,$6))
      .hadd -ms Tarih $6 $hget(Trh,$6) | .hsave -o Tarih Tarih.tprk | .hdel -ms Trh $6
    }
  }
}
on ^*:join:#Sohbet,#Radyo,#Oyun:{
  if $token($hget(Tarih,$nick),1-2,47) == $token($date,1-2,47) {
    mode # +v $nick
    msg # Doğum gününüz kutlu olsun,4 $nick
  }
}
on *:start:if $isfile(Tarih.tprk) { .hmake Tarih | .hload Tarih Tarih.tprk }
alias _tr return $replace($1-,Ç,Ç,Ä°,İ,ü,ü,ÅŸ,ş,ÄŸ,ğ,ç,ç,ı,ı,ö,ö,Å,Ş,Ä,Ğ,Ãœ,Ü,Ö,Ö)
on *:sockopen:tarih*:{ 
  if ($sockerr) { .sockclose $sockname | return }
  var %:sockmark $token($sock($sockname).mark,2,191), %:hesap $+(gun=,$token(%:sockmark,1,47),&ay=,$token(%:sockmark,2,47),&yil=,$token(%:sockmark,3,47))
  sockwrite -nt $sockname POST /yas-hesaplama-dogum-gunu-hesaplama-burc-hesaplama/ HTTP/1.1 
  sockwrite -nt $sockname Host: $sock($sockname).addr
  sockwrite -nt $sockname Connection: keep-alive
  sockwrite -nt $sockname Content-length: $len(%:hesap)
  sockwrite -nt $sockname Accept: text/html, application/xhtml+xml
  sockwrite -nt $sockname User-Agent: Mozilla/4.0 (compatible; MSIE 8.0; Windows NT 6.1; Trident/4.0; SLCC2; .NET CLR 2.0.50727; .NET CLR 3.5.30729; .NET CLR 3.0.30729)
sockwrite -nt $sockname 
  sockwrite -nt $sockname %:hesap
}
on *:sockread:tarih*:{ 
  var %:tarih | sockread %:tarih | tokenize 32 $_tr(%:tarih)
  if $regex($1-,/<b>(.+?) günü <\/b>doğdunuz/i) { msg $token($sock($sockname).mark,1,191) $+(4,$regml(1),) günü doğdunuz }
  if $regex($1-,/tam olarak (.+?) yaşındasınız/i) { msg $token($sock($sockname).mark,1,191) $+(4,$regml(1),) yaşındasınız }
  if $regex($1-,/Yaşanılan Toplam Süre<\/b>\=(.+?)<br> <b>/i) { msg $token($sock($sockname).mark,1,191) Yaşanılan Toplam Süre =4 $regml(1) }
  if $regex($1-,/<b>Yaşadığın Ay Sayısı\:<\/b>(.+?)<br>/i) { msg $token($sock($sockname).mark,1,191) Yaşadığın Ay Sayısı =4 $regml(1) }
  if $regex($1-,/<b>Yaşadığın Gün Sayısı\:<\/b>(.+?)<br>/i) { msg $token($sock($sockname).mark,1,191) Yaşadığın Gün Sayısı =4 $regml(1) }
  if $regex($1-,/<b>Yaşadığın Saat Sayısı\:<\/b>(.+?)<br>/i) { msg $token($sock($sockname).mark,1,191) Yaşadığın Saat Sayısı =4 $regml(1) }
  if $regex($1-,/<b>Yaşadığın Dakika Sayısı\:<\/b>(.+?)<br>/i) { msg $token($sock($sockname).mark,1,191) Yaşadığın Dakika Sayısı =4 $regml(1) }
  if $regex($1-,/Doğum gününüze kalan süre<\/b>\:(.+?)<br>/i) { msg $token($sock($sockname).mark,1,191) Doğum gününüze kalan süre =4 $regml(1) }
  if $regex($1-,/Burcunuz\:<\/b>(.+?)<br>/i) { msg $token($sock($sockname).mark,1,191) Burcunuz =2 $regml(1) | sockclose $sockname }
}
Normalde $ctime ile daha basit yazılıyor hatta yazmıştım ama 1970 öncesini göstermiyor(/echo -a $asctime(0)) ondan dolayı siteden çektiriyorum..
 
Alt 01 Temmuz 2021, 12:13   #2
She
✰ ÖzeL..
She - ait Kullanıcı Resmi (Avatar)

Standart

Emeğinize sağlık paylaşım için teşekkür ederiz @[Üye Olmadan Linkleri Göremezsiniz. Üye Olmak için TIKLAYIN...]

________________

~ E & B ~
 


Konuyu Toplam 1 Üye okuyor. (0 Kayıtlı üye ve 1 Misafir)
 
Seçenekler
Stil

Yetkileriniz
Konu Acma Yetkiniz Yok
Cevap Yazma Yetkiniz Yok
Eklenti Yükleme Yetkiniz Yok
Mesajınızı Değiştirme Yetkiniz Yok

BB code is Açık
Smileler Açık
[IMG] Kodları Açık
HTML-Kodu Kapalı
Trackbacks are Kapalı
Pingbacks are Kapalı
Refbacks are Kapalı





Tüm Zamanlar GMT +3 Olarak Ayarlanmış. Şuanki Zaman: 12:13.