Kod

; ======= ARKADAŞ SİSTEMİ =======

menu nicklist {
  Arkadaş İşlemleri
  .Arkadaş Ekle:./eklearkadas $1
  .Arkadaş Sil:./silarkadas $1
  .Arkadaş Listesi Göster:/friends
}
menu query {
  Arkadaş İşlemleri
  .Arkadaş Ekle:./eklearkadas $1
  .Arkadaş Sil:./silarkadas $1 | if $query($1) { window -c $1 }
  .Arkadaş Listesi Göster:/friends
}
menu @arkadaslar {
  Arkadaş İşlemleri
  .Arkadaş Ekle:./eklearkadas $1
  .Arkadaş Sil:./silarkadas $1
  .Arkadaş Listesi Göster:/friends
}
; ===== EKLE ARKADAŞ =====
alias eklearkadas {
  if ($read(friends.txt, w, $1)) {
    echo -a $1 7zaten arkadaş listende.
  }
  else {
    write friends.txt $1
    echo -a $1 3Arkadaş listene eklendi.
    ; Dialog açıksa listeyi güncelle
    if ($dialog(flist)) {
      did -a flist 1 $1
      dialog -v flist
    }
    query $1
    ison $1
    .timer 1 2 showstatus $1
  }
}

; ===== SİL ARKADAŞ =====
alias silarkadas {
  if (!$read(friends.txt, w, $1)) {
    echo -a $1 2Arkadaş listende yok.
  }
  else {
    write -dw $1 friends.txt
    echo -a $1 4Arkadaş listesinden silindi.
    dline -l @Arkadaslar $fline(@arkadaslar,$1)
    ; Dialog açıksa listeyi güncelle
    if ($dialog(flist)) {
      did -r flist 1
      var %i 1
      while ($read(friends.txt, %i)) {
        did -a flist 1 $v1
        inc %i
      }
      dialog -v flist
    }
  }
}

; ===== ARKADAŞ LİSTESİ =====
alias friends {
  if (!$dialog(flist)) { 
    dialog -m flist flist 
  }
  else {
    did -r flist 1
    var %i 1
    while ($read(friends.txt, %i)) {
      did -a flist 1 $v1
      inc %i
    }
    dialog -v flist
  }
}

; ===== STATUS POPUP FONKSİYONU =====
alias showstatus {
  var %nick = $1
  var %status
  if ($nick(#,%nick)) || ($address(%nick,1)) { %status = $chr(3)04 %nick online! }
  else { %status = $chr(3)14 %nick offline. }
  if (!$dialog(status)) { 
    dialog -m status status
  }
  did -a status 1 %nick  
  if $fline(@Arkadaslar,%nick) { did -c status 3 } 
  if !$fline(@Arkadaslar,%nick) { did -c status 4 }
  dialog -v status
}

; ===== DIALOGLAR =====

dialog flist {
  title "Arkadaşlar"
  size -1 -1 150 200
  list 1, 5 5 140 150, size vsbar
  button "Kapat", 2, 50 165 50 20, ok
}
dialog status {
  title "Durum Bilgisi"
  size -1 -1 142 118
  option pixels
  button "Tamam", 2, 42 93 50 20, ok
  text "", 1, 6 10 101 16
  radio "ONLINE", 3, 29 34 59 20, disable
  radio "OFFLINE", 4, 29 58 73 20, disable
}


; ===== DIALOG INIT =====
on *:DIALOG:flist:init:0:{
  var %i 1
  while ($read(friends.txt, %i)) {
    did -a $dname 1 $v1
    inc %i
  }
}


; ===== DIALOG ÇİFT TIK =====

on *:DIALOG:flist:dclick:1:{
  var %sel = $did(flist,1).seltext
  if (%sel != $null) {
    var %nick = $did(flist,1,%sel).seltext
    if (%nick != $null) { 
      query %nick
      showstatus %nick
    }
  }
}

on *:DIALOG:status:sclick:2:{
  dialog -x status
}

; ===== ONLINE KONTROL =====


on *:CONNECT:{
  .timerfriends 0 5 checkfriends
}

alias checkfriends {
  var %i 1, %nick
  while ($read(friends.txt, %i)) {
    var %nick = %nick $v1
    inc %i
  }
  set -eu3 %ison_nick  OK
  .ison %nick

}
raw 303:*:{
  if (%ison_nick && $active != @Arkadaslar) {
    clear -l @Arkadaslar 
    if !$window(@Arkadaslar) { 
      window -aeln @Arkadaslar
    }
    aline @arkadaslar ======= ONLINE ARKADAS LISTESI ========
    tokenize 32 $2-
    aline @Arkadaslar $*
  }
  haltdef
}