Kod

menu * {
  • Webanalysis Proxy Koruması
  .Aç:/enable #Webanalysis | echo -a 3Webanalysis Proxy Koruması Aktif.Proxy İpler Atılacak.
  .Kapat:/disable #Webanalysis | echo -a 4Webanalysis Proxy Koruması Aktif Değil. Proxy İpler Atılmayacak.
  ..Durum < $replace($group(#Webanalysis).status, off, Kapalı, on, Açık) >:.
}
#Webanalysis off
raw 352:*:{
  sockclose proxysorgud-*
  haltdef
  proxysorgu $4
}
on *:snotice:*:{
  if $regex($1-,/Client connecting (on port|at) (.+)\: (.+) \((.+)@(.+)\)/Si) {
    var %_port = $regml(2), %_nick $regml(3), %_ident $regml(4), %_ip $regml(5)
    ;- Muaf port ekleme.
    if $istok(Port1 Port2 Port3,%_port,32) { return }
    ;- Muaf nick ekleme
    elseif $istok(Nick1 Nick2 Nick3,%_nick,32) { return }
    ;- Muaf ident ekleme
    elseif $istok(ident ident1 ident2,%_ident,32) { return }
    ;- Muaf IP ekleme
    elseif $istok(ip1 ip2 ip3,%_ip,32 ) { return }
    who +I %_nick
  }
} 
alias proxysorgu {
  sockopen -e $+(proxysorgud-,$1) awebanalysis.com 443 
  set -e %proxyip $1
}
on *:sockopen:proxysorgud-*: {
  var %proxysorgud sockwrite -tn $sockname
  %proxysorgud GET $+(/en/ip-lookup/,$gettok($sockname,-1,$asc(-)),/) HTTP/1.1
  %proxysorgud Host: awebanalysis.com
  %proxysorgud User-Agent: Mozilla/5.0 (Windows NT 10.0; Win64; x64; rv:104.0) Gecko/20100101 Firefox/104.0
  %proxysorgud Accept: text/html,application/xhtml+xml,application/xml;q=0.9,image/avif,image/webp,*/*;q=0.8
  %proxysorgud Accept-Language: tr-TR,tr;q=0.8,en-US;q=0.5,en;q=0.3
  %proxysorgud Alt-Used: awebanalysis.com
  %proxysorgud Connection: close
  %proxysorgud $crlf
  %proxysorgud $crlf
}
on *:sockread:proxysorgud-*:{
  :proxysorgud | sockread -f %proxysorgud
  if ($sockbr == 0) return
  if (*<td><span class="proxy-not-found">Proxy Not Detected</span></td>* iswm %proxysorgud ) { 
    echo -a :: %proxyip 3Numaralı ip adresi PROXY Değildir.
  }
  elseif (*<td><span class="proxy-found">Proxy Detected</span></td>* iswm %proxysorgud ) {
    if (!$window(@Proxy)) { window -en @Proxy } | echo -t @Proxy :: %proxyip 4Numaralı ip adresi PROXY'dir.
    gzline $+(*@,%proxyip) +5h 4Proxy Yasak! 
  }
  elseif *<td class="leading-relaxed"><b>* iswm %proxysorgud {  
  if (!$window(@Proxy)) { window -en @Proxy } | echo -t @Proxy 4Proxy Türü  $remove(%proxysorgud,$chr(44)<b>,</b>,</td>,<td class="leading-relaxed"><b>) }

  goto proxysorgud
}
#Webanalysis End