mIRC - Telegram Botu - IRCRehberi.Net- Türkiyenin En iyi IRC ve Genel Forum Sitesi

**SaDo** · 08 Mart 2026, 03:30

Merhaba arkadaşlar uzak masaüstünde sürekli nickim park halinde olduğu için gelen mesajlara anında cevap verememe gibi bir sorunum vardı onu Telegramda bir bot oluşturarak hallettik hazırladığımız bu uygulamayı sizlerlede paylaşmak istedik.

Telegramdan oluşturduğunuz botun ID si ve Tokenini aldıktan sonra indireceğiniz uygulamaya gerekli bilgileri girin ve mIRC 'inize parça kodu ekleyin geriye kalan tüm işlemleri uygulama halledecektir. Size birisi özelden yazdığında telegramdan görebilecek ve cevap verebileceksiniz. mIRC Scriptinizle tamamen eş zamanlı çalışacak basit bir uygulama bir çoğunuzun işini görecektir. Bir kaç ekran resmi paylaşayım kurmakta zorluk çeken arkadaşlar olursa irc.vaybe.net gelebilir SaDo veya Emrehan nickine yazabilirsiniz veya çok gerekirse kısa detaylı bir anlatım yaparım

NOT: Bilgisayarınız açık kalacaksa çalışmaya devam eder veya Uzak masaüstü kullanan arkadaşlar tam olarak faydalanabilir. Uygulama kapandıktan sonra çalışmayacaktır.

Telegram Görüntüsü;

mIRC - Telegram Botu

Uygulama Görüntüsü ;

mIRC - Telegram Botu

Özelinize yazılanı telegramdan yanıtla diyerek görseldeki gibi direkt cevaplayabilirsiniz.

mIRC e eklenecek Remote;

Kod

on *:TEXT:*:?: {
  if ($nick == $me) return

  var %sunucu = $tg_encode($server)
  var %nick   = $tg_encode($nick)
  var %mesaj  = $tg_encode($1-)
  var %body   = sunucu= $+ %sunucu $+ &nick= $+ %nick $+ &mesaj= $+ %mesaj
  var %sock   = tg_ $+ $ticks
  set -eu30 $+(%,tg.body.,%sock) %body
  set -eu30 $+(%,tg.nick.,%sock) $nick

  sockopen %sock 127.0.0.1 5000
}

on *:START: {
  .timerTelegramCevap 0 2 tg_cevap_kontrol
  echo -a 03mIRC Telegram sistemi aktif.
}

alias tg_cevap_kontrol {
  var %klasor = C:\mIRC_Telegram_Ozel_Mesaj\
  if (!$isdir(%klasor)) return

  var %f = $findfile(%klasor, cevap_*.txt, 1)
  while (%f) {
    var %veri = $read(%f, 1)
    .remove %f

    var %nick = $gettok(%veri, 1, 124)
    var %msg = $gettok(%veri, 2-, 124)

    if (%nick) && (%msg) {
      msg %nick %msg
    }

    var %f = $findfile(%klasor, cevap_*.txt, 1)
  }
}

alias tg_encode {
  var %x = $1-
  %x = $replace(%x, %, $+($chr(37),25))
  %x = $replace(%x, $chr(13), )
  %x = $replace(%x, $chr(10), $+($chr(37),0A))
  %x = $replace(%x, &, $+($chr(37),26))
  %x = $replace(%x, +, $+($chr(37),2B))
  %x = $replace(%x, =, $+($chr(37),3D))
  %x = $replace(%x, ?, $+($chr(37),3F))
  %x = $replace(%x, #, $+($chr(37),23))
  %x = $replace(%x, $chr(32), $+($chr(37),20))
  return %x
}

on *:SOCKOPEN:tg_*: {
  if ($sockerr) {
    unset $+(%,tg.body.,$sockname)
    unset $+(%,tg.nick.,$sockname)
    return
  }

  var %body = $($+(%,tg.body.,$sockname),2)
  var %len = $len(%body)

  sockwrite -tn $sockname POST /mirc_mesaj HTTP/1.1
  sockwrite -tn $sockname Host: 127.0.0.1:5000
  sockwrite -tn $sockname Content-Type: application/x-www-form-urlencoded
  sockwrite -tn $sockname Content-Length: %len
  sockwrite -tn $sockname Connection: close
  sockwrite -tn $sockname
  sockwrite -n $sockname %body
}

on *:SOCKCLOSE:tg_*: {
  unset $+(%,tg.body.,$sockname)
  unset $+(%,tg.nick.,$sockname)
}

Uygulamayı İndirmek İçin:

[Üye Olmadan Linkleri Göremezsiniz. Lütfen Üye Olmak için TIKLAYIN...]

Keyifli Forumlar