| Zadrich |
30 Ocak 2020 22:09 |
Girişte ÜLKE Yasaklamak isterseniz
Kod:
on *:text:*:#OperLog:{
if $regex($1,/^[!.][uüÜ]lke/Si) {
if !$2 { msg # Lütfen !ulke <ekle|sil|list> olarak belirtiniz. }
elseif $regex($2,/^ekle$/Si) {
if !$3 { msg # Lütfen !ulke ekle <Ulke> olarak belirtiniz. }
elseif $regex($3,/Bel[ıiİ]rs[ıiİ]z/Si) { msg # Böyle bir ülke yok :) }
elseif $hget(Ulke,$strip($3)) { msg # $strip($3) ülkesi yasak listesinde zaten ekli. }
else { .hadd -ms Ulke $strip($3) $nick | .hsave -o Ulke Ulke.Yasak | msg # $strip($3) yasak ülke listesine eklendi. }
}
elseif $regex($2,/^s[ıiİ]l$/Si) {
if !$3 { msg # Lütfen !yasak sil <Ulke> olarak belirtiniz. }
elseif !$hget(Ulke,$strip($3)) { msg # $strip($3) yasak ülke listesinde ekli değil. }
else { .hdel -ms Ulke $strip($3) | .hsave -o Ulke Ulke.Yasak | msg # $strip($3) yasak ülke listesinden silindi. }
}
elseif $regex($2,/^l[ıiİ]st$/Si) {
if !$hget(Ulke,0).data { msg # Yasak ülke listesi boş. }
else {
msg # Yasak Ülke Listesi
msg # -
var %:t = 1 | while %:t <= $hget(Ulke,0).data {
msg # $+(%:t,.,$chr(41)) Ülke:4 $hget(Ulke,%:t).item Ekleyen:2 $hget(Ulke,%:t).data
inc %:t
}
msg # -
msg # Yasak Ülke Listesi Sonu
}
}
}
}
on *:start:if $isfile(Ulke.Yasak) { .hmake Ulke | .hload -o Ulke Ulke.Yasak }
on *:snotice:*:if $regex($1-,/Client connecting (on port|at) .+\: (.+) \(.+@.+\)/Si) { who +I $regml(2) }
raw 352:*:{ var %:r $r(1000,99999) | sockopen $+(ulke,%:r) www.ipaddresslocation.org 80 | sockmark $+(ulke,%:r) $+($4,¿,$6) }
on *:sockopen:ulke*:{
if ($sockerr) { .sockclose $sockname | return }
sockwrite -nt $sockname GET $+(/ip-address-locator.php?lookup=,$token($sock($sockname).mark,1,191)) HTTP/1.1
sockwrite -nt $sockname Host: $sock($sockname).addr
sockwrite -nt $sockname Connection: keep-alive
sockwrite -nt $sockname Accept: text/html,application/xhtml+xml,application/xml;q=0.9,image/webp,*/*;q=0.8
sockwrite -nt $sockname User-Agent: Mozilla/5.0 (Windows NT 6.1) AppleWebKit/537.36 (KHTML, like Gecko) Chrome/40.0.2214.111 Safari/537.36
sockwrite -nt $sockname $crlf
}
on *:sockread:ulke*:{
var %:ulke | sockread -f %:ulke | tokenize 32 %:ulke
if $regex($1-,/IP Country:<\/i> <b>(.+)<\/b>/i) { .hadd -ms Country $sockname $iif($regml(1),$regml(1),Belirsiz) }
elseif $regex($1-,/IP City: <b>(.+)<\/b>/i) { .hadd -ms Sehir $sockname $iif($regml(1),$regml(1),Belirsiz) }
elseif $regex($1-,/ISP Provider:<\/i> <b>(.+)<\/b>/i) {
$iif(!$window(@Network),window -e @Network)
echo -t @Network [ GİRİŞ ] Nick:4 $token($sock($sockname).mark,2,191) - IP:4 $token($sock($sockname).mark,1,191) - Ülke:2 $hget(Country,$sockname) - Şehir:2 $hget(Sehir,$sockname) - ISP:5 $iif($regml(1),$regml(1),Belirsiz) $iif($hget(Ulke,$hget(Country,$sockname)),- 4Yasak Ülke Girişi!)
if $hget(Ulke,$hget(Country,$sockname)) { .gzline $+(*@,$token($sock($sockname).mark,1,191)) +5h Yasak Ülke Girişi }
.hdel -ms Country $sockname | .hdel -ms Sehir $sockname | sockclose $sockname
}
}
Klavyeniz den Alt + R Tuşlarına Basarak Acılan Pencere de REMOTE Kısmına Basıyoruz
Ardından DOSYA Kısmına Basarak Yeni Bir Sayfa acarak içine atıyoruz ve kapatıyoruz
-
Kendinize göre uyarlamayı unutmayınız. |
