Kod

alias rip return radyo.IdealSohbet.com
alias rport return 9352
 
on *:text:*:#DJ:{
  if $regex($1,/^[!.-]kay[ıiİ]t$/Si) {
    if !$2 { msg # Lütfen 4!kayit nick belirtiniz. 4ORN: !kayit Sys }
    elseif %:knick { msg # Şuan kayit yapılmaktadır lütfen 4!durdur komutunu uygulayınız. }
    else {
      $iif(!$isdir(MP3),mkdir MP3)
      set %:knick $+($date(d-m-yyyy),_,$lower($strip($2)),.mp3)
      msg # $strip($2) nicki için yayın kayıt başlamıştır kayıt dosyası; %:knick
      msg # Kayıtı durdurmak için yada DJ değişikliği için lütfen 4!durdur yazınız.
      sockopen rkayit $rip $rport
    }
  }
  elseif $regex($1,/^[!.-]durdur$/Si) {
    if !%:knick { msg # Şuan herhangi bir kayıt yapılmaktadır.. }
    else {
      msg # DJ4 $token($token(%:knick,2,95),1,46) için kayıt durdurulmuştur..
      msg # Yayın kayıt dosyası;2 %:knick olarak kayıt edilmiştir..
      unset %:knick
      sockclose rkayit
    }
  }
}
on *:sockopen:rkayit:{
  if ($sockerr) { sockclose $sockname }
  else {
    sockwrite -nt $sockname GET / HTTP/1.1
    sockwrite -nt $sockname Host: $sock($sockname).addr
    sockwrite -nt $sockname accept: */* 
    sockwrite -nt $sockname icy-metadata:0 
    sockwrite -nt $sockname connection: close 
    sockwrite -nt $sockname $crlf
  }
}
on *:sockread:rkayit:{
  sockread -f &rkayit
  .bwrite $+(MP3/,%:knick) -1 -1 &rkayit
}